struct MappingClassGroup{N} <: GAPGroup end

MappingClassGroup(args::Dict) = MappingClassGroup{args["MCG"]}()

name(G::MappingClassGroup{N}) where N = "MCG(N)"

function group(G::MappingClassGroup{N}) where N

    if N < 2
        throw("Genus must be at least 2!")
    elseif N == 2
        MCGroup = Groups.FPGroup(["a1","a2","a3","a4","a5"]);
        S = gens(MCGroup)

        n = length(S)
        A = prod(reverse(S))*prod(S)

        relations = [
           [Comm(S[i], S[j]) for i in 1:n for j in 1:n if abs(i-j) > 1]...,
           [S[i]*S[i+1]*S[i]*inv(S[i+1]*S[i]*S[i+1]) for i in 1:G.n-1]...,
           (S[1]*S[2]*S[3])^4*inv(S[5])^2,
           Comm(A, S[1]),
           A^2
           ]

       relations = [relations; [inv(rel) for rel in relations]]
       Groups.add_rels!(MCGroup, Dict(rel => MCGroup() for rel in relations))
       return MCGroup

    else
        MCGroup = Groups.FPGroup(["a$i" for i in 0:2N])
        S = gens(MCGroup)

        a0 = S[1]
        A = S[2:end]
        k = length(A)

        relations = [
            [Comm(A[i], A[j]) for i in 1:k for j in 1:k if abs(i-j) > 1]...,
            [Comm(a0, A[i]) for i in 1:k if i != 4]...,
            [A[i]*A[(i+1)]*A[i]*inv(A[i+1]*A[i]*A[i+1]) for i in 1:k-1]...,
            A[4]*a0*A[4]*inv(a0*A[4]*a0)
            ]

        # 3-chain relation
        c = prod(reverse(A[1:4]))*prod(A[1:4])
        b0 = c*a0*inv(c)
        push!(relations, (A[1]*A[2]*A[3])^4*inv(a0*b0))

        # Lantern relation
        b1 = inv(A[4]*A[5]*A[3]*A[4])*a0*(A[4]*A[5]*A[3]*A[4])
        b2 = inv(A[2]*A[3]*A[1]*A[2])*b1*(A[2]*A[3]*A[1]*A[2])
        u  = inv(A[6]*A[5])*b1*(A[6]*A[5])
        x  = prod(reverse(A[2:6]))*u*prod(inv.(A[1:4]))
        b3 = x*a0*inv(x)
        push!(relations, a0*b2*b1*inv(A[1]*A[3]*A[5]*b3))

        # Hyperelliptic relation
        X = prod(reverse(A))*prod(A)

        function n(i::Int, b=b0)
            if i == 1
                return A[1]
            elseif i == 2
                return b
            else
                return w(i-2)*n(i-2)*w(i-2)
            end
        end

        function w(i::Int)
           (A[2i+4]*A[2i+3]*A[2i+2]* n(i+1))*(A[2i+1]*A[2i]  *A[2i+2]*A[2i+1])*
           (A[2i+3]*A[2i+2]*A[2i+4]*A[2i+3])*( n(i+1)*A[2i+2]*A[2i+1]*A[2i]  )
        end

        # push!(relations, X*n(N)*inv(n(N)*X))

        relations = [relations; [inv(rel) for rel in relations]]
        Groups.add_rels!(MCGroup, Dict(rel => MCGroup() for rel in relations))

        return MCGroup
    end
end