struct SpecialAutomorphismGroup <: SymmetricGroup
    args::Dict{String,Any}
    group::AutGroup

    function SpecialAutomorphismGroup(args::Dict)
        N = args["N"]
        return new(args, AutGroup(FreeGroup(N), special=true))
    end
end

function name(G::SpecialAutomorphismGroup)
    N = G.args["N"]

    if G.args["nosymmetry"]
        return "SAutF$(N)"
    else
        return "oSAutF$(N)"
    end
end

group(G::SpecialAutomorphismGroup) = G.group

function generatingset(G::SpecialAutomorphismGroup)
    S = gens(group(G));
    return unique([S; inv.(S)])
end

function autS(G::SpecialAutomorphismGroup)
    N = G.args["N"]
    return WreathProduct(PermutationGroup(2), PermutationGroup(N))
end

###############################################################################
#
#  Action of WreathProductElems on AutGroupElem
#
###############################################################################

function AutFG_emb(A::AutGroup, g::WreathProductElem)
    isa(A.objectGroup, FreeGroup) || throw("Not an Aut(Fₙ)")
    parent(g).P.n == length(A.objectGroup.gens) || throw("No natural embedding of $(parent(g)) into $A")
    Id = parent(g.n[1])()
    powers = ((el == Id ? 0: 1) for el in g.n.elts)
    elt = A()
    Groups.r_multiply!(elt, [Groups.flip_autsymbol(i, pow=p) for (i,p) in enumerate(powers)], reduced=false)
    Groups.r_multiply!(elt, [Groups.perm_autsymbol(g.p)])
    return elt
end

function AutFG_emb(A::AutGroup, p::perm)
    isa(A.objectGroup, FreeGroup) || throw("Not an Aut(Fₙ)")
    parent(p).n == length(A.objectGroup.gens) || throw("No natural embedding of $(parent(g)) into $A")
    return A(Groups.perm_autsymbol(p))
end

function (g::WreathProductElem)(a::Groups.Automorphism)
    g = AutFG_emb(parent(a),g)
    return g*a*g^-1
end

function (p::perm)(a::Groups.Automorphism)
    g = AutFG_emb(parent(a),p)
    return g*a*g^-1
end

end