struct SpecialLinearGroup <: SymmetricGroup
    args::Dict{String,Any}
    group::AbstractAlgebra.Group

    function SpecialLinearGroup(args::Dict)
        n = args["N"]
        p = args["p"]
        X = args["X"]

        if p == 0
            G = MatrixSpace(Nemo.ZZ, n, n)
        else
            G = MatrixSpace(FiniteField(p), n, n)
        end
        return new(args, G)
    end
end

function name(G::SpecialLinearGroup)
    N = G.args["N"]
    p = G.args["p"]
    X = G.args["X"]

    if p == 0
       R = (X ? "Z[x]" : "Z")
    else
       R = "F$p"
    end
    if G.args["nosymmetry"]
        return "SL($N,$R)"
    else
        return "oSL($N,$R)"
    end
end

group(G::SpecialLinearGroup) = G.group

function E(i::Int, j::Int, M::MatSpace, val=one(M.base_ring))
    @assert i≠j
    m = one(M)
    m[i,j] = val
    return m
end

function generatingset(G::SpecialLinearGroup)
    n = G.args["N"]
    p = G.args["p"]
    X = G.args["X"]
    SL = group(G)
    indexing = [(i,j) for i in 1:n for j in 1:n if i≠j]

    p > 0 && X && throw("SL(n, F_p[x]) not implemented")

    if !X
        S = [E(idx[1],idx[2],SL) for idx in indexing]
    else
        r = G.args["radius"]
        S = [E(i,j,SL,v) for (i,j) in indexing for v in [1, 100*r]]
    end
    return unique([S; inv.(S)])
end

function autS(G::SpecialLinearGroup)
    N = G.args["N"]
    return WreathProduct(PermutationGroup(2), PermutationGroup(N))
end

###############################################################################
#
#  Action of WreathProductElems on Nemo.MatElem
#
###############################################################################

function matrix_emb(n::DirectProductGroupElem, p::perm)
    Id = parent(n.elts[1])()
    elt = diagm([(-1)^(el == Id ? 0 : 1) for el in n.elts])
    return elt[:, p.d]
end

function (g::WreathProductElem)(A::MatElem)
    g_inv = inv(g)
    G = matrix_emb(g.n, g_inv.p)
    G_inv = matrix_emb(g_inv.n, g.p)
    M = parent(A)
    res = M(G_inv)
    Nemo.mul!(res, A, res)
    return Nemo.mul!(res, M(G), res)
end

function (p::perm)(A::MatElem)
    length(p.d) == A.r == A.c || throw("Can't act via $p on matrix of size ($(A.r), $(A.c))")
    return p*A*inv(p)
end