PlanetEditor/grk/planet-editor/shaders/shader_sun.frag

#version 430 core
layout (location = 0) out vec4 outColor;
layout (location = 1) out vec4 BrightColor;

uniform vec3 lightPos;
uniform vec3 lightColor;

uniform vec3 cameraPos;

uniform bool glowCheck;
uniform bool toneMappingCheck;

uniform float time;

in vec3 vecNormal;
in vec3 worldPos;
in vec2 vtc;

uniform sampler2D colorTexture;

vec3 toneMapping(vec3 color)
{
	float exposure = 0.06;
	vec3 mapped = 1 - exp(-color * exposure);
	return mapped;
}

float random (in vec2 _st) {
    return fract(sin(dot(_st.xy,
                         vec2(-0.550,0.430)))*
        43758.5453123);
}

float noise (in vec2 _st) {
    vec2 i = floor(_st);
    vec2 f = fract(_st);

    float a = random(i);
    float b = random(i + vec2(1.0, 0.0));
    float c = random(i + vec2(0.0, 1.0));
    float d = random(i + vec2(1.0, 1.0));

    vec2 u = f * f * (3.0 - 2.0 * f);

    return mix(a, b, u.x) +
            (c - a)* u.y * (1.0 - u.x) +
            (d - b) * u.x * u.y;
}

#define NUM_OCTAVES 5

float fbm ( in vec2 _st) {
    float v = 0.0;
    float a = 0.5;
    vec2 shift = vec2(100.0);

    mat2 rot = mat2(cos(0.5), sin(0.5),
                    -sin(0.5), cos(0.5));
    for (int i = 0; i < NUM_OCTAVES; ++i) {
        v += a * noise(_st);
        _st = rot * _st * 2.0 + shift;
        a *= 0.75;
    }
    return v;
}

vec3 noiseColor() {
    vec2 st = vtc.xy * 9.;
    vec3 color = vec3(0.0);

    vec2 q = vec2(0.);
    q.x = fbm(st + 0.0 * time);
    q.y = fbm(st + vec2(1.0));

    vec2 r = vec2(0.);
    r.x = fbm(st + 1.0 * q + vec2(1.7, 9.2) + 0.15 * time);
    r.y = fbm(st + 1.0 * q + vec2(8.3, 2.8) + 0.12 * time);

    float f = fbm(st+r);

    color = mix(vec3(0.667,0.640,0.088),
                vec3(0.667,0.520,0.134),
                clamp((f*f)*4.640,0.712,0.056));

    color = mix(color,
                vec3(0.165,0.111,0.036),
                clamp(length(q),0.072,0.408));

    color = mix(color,
                vec3(1.000,0.306,0.143),
                clamp(length(r.x),0.0,1.0));

    vec3 noiseColor = vec3((f*f*f+1.384*f*f+1.044*f)*color);

    return noiseColor;
}

void main()
{
	vec3 normal = normalize(vecNormal);
    vec3 viewDir = normalize(cameraPos - worldPos);

	vec3 textureColor = texture2D(colorTexture, vtc).rgb;

    if (glowCheck)
	{
		float glowDot = dot(normal, viewDir);
		vec3 glowColor = vec3(1.0, 0.08, 0.02);
        textureColor = mix(textureColor, glowColor, pow(1 - glowDot, 2));
	}

	vec3 mixedColor;
    
    if (glowCheck)
    {
        vec3 noiseColor = noiseColor();
        mixedColor = mix(textureColor, noiseColor, 0.35);
    }
    else
        mixedColor = textureColor * lightColor * 0.2f;

    vec3 toneMappedColor;

    if (toneMappingCheck)
    {
        vec3 distance = lightColor / pow(length(lightPos - worldPos), 2.0) * 100;
        toneMappedColor = toneMapping(mixedColor * distance);

        //gamma correction
        toneMappedColor = pow(toneMappedColor, vec3(1.0/2.2));
    }
    else
        toneMappedColor = mixedColor;

    vec3 finalColor = toneMappedColor;
	  
    float brightness = dot(finalColor, vec3(0.2126, 0.7152, 0.0722));
    
	if(brightness > 0.2)
        BrightColor = vec4(finalColor, 1.0);
    else
        BrightColor = vec4(0.0, 0.0, 0.0, 1.0);

	outColor = vec4(finalColor, 1.0);
}