PlanetEditor/grk/cw 6/shaders/shader_pbr.frag

#version 430 core

layout (location = 0) out vec4 outColor;
layout (location = 1) out vec4 BrightColor;

float AMBIENT = 0.05;
float PI = 3.14159;

uniform sampler2D colorTexture;
uniform sampler2D textureNormal;

uniform float exposition;
uniform float metallic;
uniform float roughness;

uniform vec3 cameraPos;

uniform vec3 sunDir;
uniform vec3 sunColor;

uniform vec3 lightPos;
uniform vec3 lightColor;

uniform bool atmosphereCheck;
uniform bool toneMappingCheck;

uniform float time;

uniform float cloudIntensity;
uniform float cloudMotion;
uniform float cloudBrightness;

in vec3 vecNormal;
in vec3 worldPos;
in vec2 vtc;

in vec3 viewDirTS;
in vec3 lightDirTS;
in vec3 sunDirTS;

float DistributionGGX(vec3 normal, vec3 H, float roughness)
{
    float a = roughness * roughness;
    float a2 = a * a;
    float NdotH = max(dot(normal, H), 0.0);
    float NdotH2 = NdotH * NdotH;
	
    float num = a2;
    float denom = (NdotH2 * (a2 - 1.0) + 1.0);
    denom = PI * denom * denom;
	
    return num / denom;
}

float GeometrySchlickGGX(float NdotV, float roughness)
{
    float r = (roughness + 1.0);
    float k = (r * r) / 8.0;

    float num = NdotV;
    float denom = NdotV * (1.0 - k) + k;
	
    return num / denom;
}

float GeometrySmith(vec3 normal, vec3 V, vec3 lightDir, float roughness)
{
    float NdotV = max(dot(normal, V), 0.0);
    float NdotL = max(dot(normal, lightDir), 0.0);
    float ggx2 = GeometrySchlickGGX(NdotV, roughness);
    float ggx1 = GeometrySchlickGGX(NdotL, roughness);
	
    return ggx1 * ggx2;
}

vec3 fresnelSchlick(float cosTheta, vec3 F0)
{
    return F0 + (1.0 - F0) * pow(clamp(1.0 - cosTheta, 0.0, 1.0), 5.0);
} 

vec3 PBRLight(vec3 lightDir, vec3 radiance, vec3 normal, vec3 V, vec3 color)
{
	float diffuse = max(0, dot(normal, lightDir));

	vec3 F0 = vec3(0.04); 
    F0 = mix(F0, color, metallic);

    vec3 H = normalize(V + lightDir);    
        
    // cook-torrance brdf
    float NDF = DistributionGGX(normal, H, roughness);        
    float G = GeometrySmith(normal, V, lightDir, roughness);      
    vec3 F = fresnelSchlick(max(dot(H, V), 0.0), F0);       
        
    vec3 kS = F;
    vec3 kD = vec3(1.0) - kS;
    kD *= 1.0 - metallic;	  
        
    vec3 numerator = NDF * G * F;
    float denominator = 4.0 * max(dot(normal, V), 0.0) * max(dot(normal, lightDir), 0.0) + 0.0001;
    vec3 specular = numerator / denominator;  
            
    // add to outgoing radiance Lo
    float NdotL = max(dot(normal, lightDir), 0.0);   
	return (kD * color / PI + specular) * radiance * NdotL;
}

vec3 toneMapping(vec3 color)
{
	float exposure = 0.06;
	vec3 mapped = 1 - exp(-color * exposure);
	return mapped;
}

float random (in vec2 st)
{
    return fract(sin(dot(st.xy,
                         vec2(32.9898,128.233)))*
        43758.5453123);
}

float noise (in vec2 st)
{
    vec2 i = floor(st);
    vec2 f = fract(st);

    float a = random(i);
    float b = random(i + vec2(1.0, 0.0));
    float c = random(i + vec2(0.0, 1.0));
    float d = random(i + vec2(1.0, 1.0));

    vec2 u = f * f * (3.0 - 2.0 * f);

    return mix(a, b, u.x) +
            (c - a)* u.y * (1.0 - u.x) +
            (d - b) * u.x * u.y;
}

#define OCTAVES 6
float fbm (in vec2 st)
{
    // Initial values
    float value = 0.0;
    float amplitude = .5;
    float frequency = 0.;

    // Loop of octaves
    for (int i = 0; i < OCTAVES; i++) {
        value += amplitude * noise(st);
        st *= 2.;
        amplitude *= .5;
    }
    return value;
}

vec3 noiseColor()
{
    vec2 st = vtc.xy;
    vec2 mirroredSt = vec2(1.0 - st.x, st.y);
    
    float timeOffset = time * cloudMotion;
    st.x -= timeOffset;
    mirroredSt.x += timeOffset; // Inverse direction for mirrored effect

    st.x = fract(st.x);
    mirroredSt.x = fract(mirroredSt.x);

    vec3 color = vec3(fbm(st * cloudIntensity));
    vec3 mirroredColor = vec3(fbm(mirroredSt * cloudIntensity));

    float blend = smoothstep(0.45, 0.55, st.x); 

    vec3 noiseColor = mix(color, mirroredColor, blend);

    return noiseColor;
}

void main()
{
    vec3 normal = normalize(vecNormal);
    vec3 viewDir = normalize(cameraPos - worldPos);
	vec3 lightDir = normalize(lightPos - worldPos);

    vec3 textureColor = texture2D(colorTexture, vtc).rgb;
    vec3 N = texture2D(textureNormal, vtc).rgb;

    vec3 normalTexture = normalize((N * 2.0 - 1.0));

    float diffuseNormal = max(0, dot(normalTexture, lightDir));

    if (atmosphereCheck)
    {
        float atmosphereDot = dot(normal, viewDir);
        vec3 atmosphereColor = vec3(0.0, 0.44, 1.0);
        textureColor = mix(textureColor, atmosphereColor, pow(1 - atmosphereDot, 3));
    }

    vec3 diffuseColor = textureColor * min(1, AMBIENT + diffuseNormal);
    vec3 toneMappedColor;

    if (toneMappingCheck)
    {
        vec3 distance = lightColor / pow(length(lightPos - worldPos), 2.0) * 10;
        toneMappedColor = toneMapping(diffuseColor * distance);
        //gamma correction
        toneMappedColor = pow(toneMappedColor, vec3(1.0/2.2));
    }
    else
        toneMappedColor = textureColor;

	vec3 ambient = AMBIENT * toneMappedColor;
	vec3 attenuatedLightColor = lightColor / pow(length(lightPos - worldPos), 2);
	vec3 illumination = ambient + PBRLight(lightDir, attenuatedLightColor, normal, viewDir, toneMappedColor);

	//sun
	illumination = illumination + PBRLight(sunDir, sunColor, normal, viewDir, toneMappedColor);

    vec3 pbrColor = vec3(1.0) - exp(-illumination * exposition);

    vec3 finalColor;

    if (atmosphereCheck)
    {
        vec3 noiseColor = noiseColor() * min(1, 20.0 * max(0.02, dot(normal, lightDir))) * lightColor * cloudBrightness;
        finalColor = mix(pbrColor, noiseColor, noiseColor.r);
    }
    else
        finalColor = pbrColor;

    float brightness = dot(finalColor, vec3(0.2126, 0.7152, 0.0722));

    if(brightness > 0.2)
        BrightColor = vec4(finalColor, 1.0);
    else
        BrightColor = vec4(0.0, 0.0, 0.0, 1.0);
   
    outColor = vec4(finalColor, 1.0);
}